<?xml version="1.0"?>
<xsl:stylesheet version="2.0" 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
  xmlns:xlink="http://www.w3.org/1999/xlink"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:functx="http://www.functx.com"
  xmlns:saxon="http://saxon.sf.net/"
  xmlns:dc="http://purl.org/dc/elements/1.1/" 
  xmlns:dcterms="http://purl.org/dc/terms"
  xmlns:math="http://www.w3.org/1998/Math/MathML"
  xmlns:svg="http://www.w3.org/2000/svg"
  xmlns:xhtml="http://www.w3.org/1999/xhtml"
  exclude-result-prefixes="xsl xlink xs functx saxon dc dcterms math svg xhtml"
  >

<xsl:output method="xhtml" encoding="utf-8"/>

<xsl:param name="echoFiguresDir"></xsl:param>
<xsl:param name="echoPageImgDir"></xsl:param>

<xsl:variable name="dictionaryServiceName" select="'http://mpdl-service.mpiwg-berlin.mpg.de/mpiwg-mpdl-lt-web/lt/GetDictionaryEntries'"/>

<xsl:template match="*:archimedes">
  <div>
    <xsl:if test="not(empty(@xml:id))"><xsl:attribute name="id"><xsl:value-of select="@xml:id"/></xsl:attribute></xsl:if>
    <xsl:attribute name="class"><xsl:value-of select="'archimedes'"/></xsl:attribute>
    <xsl:apply-templates/>
  </div>
</xsl:template>

<xsl:template match="*:expan|*:emph|*:q|*:quote|*:blockquote|*:set-off|*:reg|*:var|*:num">
  <span>
    <xsl:attribute name="class"><xsl:value-of select="name()"/></xsl:attribute>
    <xsl:copy-of select="@*"/>
    <xsl:apply-templates/>
  </span>
</xsl:template>

<xsl:template match="text">
  <xsl:variable name="contentStr" select="normalize-space(string(.))"/>
  <xsl:variable name="figures" select=".//*:figure|.//*:handwritten"/>
  <div>
    <xsl:if test="not(empty(@xml:id))"><xsl:attribute name="id"><xsl:value-of select="@xml:id"/></xsl:attribute></xsl:if>
    <xsl:attribute name="class"><xsl:value-of select="'text'"/></xsl:attribute>
    <xsl:apply-templates/>
    <xsl:if test="$contentStr = '' and empty($figures)">  <!-- test if div only contains empty nodes but no figures -->
      <div>
        <xsl:attribute name="class"><xsl:value-of select="'emptyPage'"/></xsl:attribute>
        <xsl:value-of select="'[Empty page]'"/>
      </div>
    </xsl:if>
  </div>
  <!--   Notes                      -->
  <xsl:variable name="bottomNotes" select="//*:note[contains(@position, 'foot') or empty(string(@position))]"/>
  <xsl:variable name="countBottomNotes" select="count($bottomNotes)"/>
  <xsl:if test="$countBottomNotes > 0">
    <span class="notes">
      <xsl:for-each select="$bottomNotes">
        <xsl:variable name="noteSign"><xsl:value-of select="count(./preceding::*:note) + 1"/></xsl:variable>
        <span>
          <xsl:if test="not(empty(@xml:id))"><xsl:attribute name="id"><xsl:value-of select="@xml:id"/></xsl:attribute></xsl:if>
          <xsl:attribute name="class"><xsl:value-of select="'note'"/></xsl:attribute>
          <span class="noteSign"><xsl:value-of select="$noteSign"/></span>
          <span>
            <xsl:attribute name="class"><xsl:value-of select="'noteBody foot'"/></xsl:attribute>
            <span class="noteSign"><xsl:value-of select="$noteSign"/></span>
            <xsl:apply-templates/>
          </span>
        </span>
      </xsl:for-each>
    </span>
  </xsl:if>
</xsl:template>

<xsl:template match="*:div">
  <xsl:if test="node() or normalize-space()">  <!-- test: contains nodes or is not empty -->
    <div>
      <xsl:if test="not(empty(@xml:id))"><xsl:attribute name="id"><xsl:value-of select="@xml:id"/></xsl:attribute></xsl:if>
      <xsl:attribute name="class"><xsl:value-of select="'div'"/></xsl:attribute>
      <xsl:apply-templates/>
    </div>
  </xsl:if>
</xsl:template>

<xsl:template match="*:p">
  <xsl:variable name="type" select="string(@type)"/>
  <div>
    <xsl:if test="not(empty(@xml:id))"><xsl:attribute name="id"><xsl:value-of select="@xml:id"/></xsl:attribute></xsl:if>
    <xsl:choose>
      <xsl:when test="$type = 'head'">
        <xsl:attribute name="class"><xsl:value-of select="'head bf'"/></xsl:attribute>      
        <xsl:apply-templates/>
      </xsl:when>
      <xsl:otherwise>
        <xsl:attribute name="class"><xsl:value-of select="'p'"/></xsl:attribute>      
        <xsl:apply-templates/>
      </xsl:otherwise>
    </xsl:choose>
  </div>
</xsl:template>

<xsl:template match="*:pb">
  <xsl:variable name="number">
    <xsl:choose>
      <xsl:when test="not(empty(@n))"><xsl:value-of select="@n"/></xsl:when>
      <xsl:otherwise><xsl:value-of select="count(./preceding::*:pb) + 1"/></xsl:otherwise>
    </xsl:choose>
  </xsl:variable>
  <xsl:variable name="file">
    <xsl:choose>
      <xsl:when test="not(empty(@xlink:href))"><xsl:value-of select="replace(@xlink:href, '/', '.')"/></xsl:when>
      <xsl:otherwise><xsl:value-of select="$number"/></xsl:otherwise>
    </xsl:choose>
  </xsl:variable>
  <span>
    <xsl:if test="not(empty(@xml:id))"><xsl:attribute name="id"><xsl:value-of select="@xml:id"/></xsl:attribute></xsl:if>
    <xsl:attribute name="class"><xsl:value-of select="'pb'"/></xsl:attribute>
    <span>
      <xsl:attribute name="class"><xsl:value-of select="'src'"/></xsl:attribute>
      <xsl:attribute name="title"><xsl:value-of select="concat('pageimg/', string($file))"/></xsl:attribute>
      <span>
        <xsl:attribute name="class"><xsl:value-of select="'n'"/></xsl:attribute>
        <xsl:value-of select="$number"/>
      </span>
    </span>
  </span>
</xsl:template>

<xsl:template match="*:head">
  <div>
    <xsl:if test="not(empty(@xml:id))"><xsl:attribute name="id"><xsl:value-of select="@xml:id"/></xsl:attribute></xsl:if>
    <xsl:attribute name="class"><xsl:value-of select="'head bf'"/></xsl:attribute>
    <xsl:apply-templates/>
  </div>
</xsl:template>

<!-- MathML    -->
<xsl:template match="math:*">
  <xsl:element name="{name()}" namespace="">
    <xsl:copy-of select="@*"/>
    <xsl:apply-templates/>
  </xsl:element>
</xsl:template>

<!-- SVG    -->
<xsl:template match="svg:*">
  <xsl:element name="{name()}" namespace="">
    <xsl:copy-of select="@*"/>
    <xsl:apply-templates/>
  </xsl:element>
</xsl:template>

<xsl:template match="*:figure">
  <span class="figure">
    <xsl:if test="not(empty(@xml:id))"><xsl:attribute name="id"><xsl:value-of select="@xml:id"/></xsl:attribute></xsl:if>
    <xsl:variable name="fileHref" select="replace(@xlink:href, '/', '.')"/>
    <xsl:variable name="fileName" select="concat($echoFiguresDir, '/', $fileHref)"/>
    <xsl:variable name="digilibUrl" select="concat('http://digilib.mpiwg-berlin.mpg.de/digitallibrary/jquery/digilib.html?fn=', $fileName)"/>
    <xsl:variable name="scalerUrl" select="concat('http://digilib.mpiwg-berlin.mpg.de/digitallibrary/servlet/Scaler?fn=', $fileName, '&amp;dh=200&amp;dw=200')"/>
    <xsl:variable name="ancestorWords" select="./ancestor::*:w"/>  <!-- if figure is in a word then no link within a link should be produced -->
    <xsl:choose>
      <xsl:when test="empty($ancestorWords)">
        <a href="{$digilibUrl}">
          <img>
            <xsl:attribute name="src"><xsl:value-of select="$scalerUrl"/></xsl:attribute>
          </img>
        </a>
      </xsl:when>
      <xsl:otherwise>
        <img>
          <xsl:attribute name="src"><xsl:value-of select="$scalerUrl"/></xsl:attribute>
        </img>
      </xsl:otherwise>
    </xsl:choose>
    <xsl:if test="not(empty(@number))">
      <span>
        <xsl:attribute name="class"><xsl:value-of select="'figureNumber'"/></xsl:attribute>
        <span>
          <xsl:attribute name="class"><xsl:value-of select="'figureNum'"/></xsl:attribute>
          <xsl:value-of select="string(@number)"/>
        </span>
        <span>
          <xsl:attribute name="class"><xsl:value-of select="'figureNumText'"/></xsl:attribute>
          <xsl:value-of select="concat('[', 'Figure', ' ', string(@number), ']')"/>
        </span>
      </span>
    </xsl:if>
  </span>
</xsl:template>

<xsl:template match="*:lb">
  <br>
    <xsl:if test="not(empty(@xml:id))"><xsl:attribute name="id"><xsl:value-of select="@xml:id"/></xsl:attribute></xsl:if>
    <xsl:attribute name="class"><xsl:value-of select="'lb'"/></xsl:attribute>
  </br>
</xsl:template>

<xsl:template match="*:cb">
  <br>
    <xsl:if test="not(empty(@xml:id))"><xsl:attribute name="id"><xsl:value-of select="@xml:id"/></xsl:attribute></xsl:if>
    <xsl:attribute name="class"><xsl:value-of select="'cb'"/></xsl:attribute>
  </br>
</xsl:template>

<xsl:template match="note">
  <xsl:variable name="place"><xsl:value-of select="string(@position)"/></xsl:variable>
  <xsl:variable name="noteSign"><xsl:value-of select="count(./preceding::*:note) + 1"/></xsl:variable>
  <span>
    <xsl:if test="not(empty(@xml:id))"><xsl:attribute name="id"><xsl:value-of select="@xml:id"/></xsl:attribute></xsl:if>
    <xsl:attribute name="class"><xsl:value-of select="'note'"/></xsl:attribute>
    <span class="noteSign"><xsl:value-of select="$noteSign"/></span>
    <xsl:if test="$place != '' and $place != 'foot'">
      <span>
        <xsl:attribute name="class"><xsl:value-of select="concat('noteBody ', $place)"/></xsl:attribute>
        <span class="noteSign"><xsl:value-of select="$noteSign"/></span>
        <xsl:apply-templates/>
      </span>
    </xsl:if>
  </span>
</xsl:template>

<xsl:template match="foreign">
  <xsl:variable name="lang" select="@lang"/>
  <xsl:variable name="xmllang" select="@xml:lang"/>
  <xsl:variable name="language">
    <xsl:choose>
      <xsl:when test="not(empty($xmllang))"><xsl:value-of select="$xmllang"/></xsl:when>
      <xsl:when test="not(empty($lang))"><xsl:value-of select="$lang"/></xsl:when>
      <xsl:otherwise><xsl:value-of select="''"/></xsl:otherwise>
    </xsl:choose>
  </xsl:variable>  
  <span>
    <xsl:if test="not(empty(@xml:id))"><xsl:attribute name="id"><xsl:value-of select="@xml:id"/></xsl:attribute></xsl:if>
    <xsl:attribute name="class"><xsl:value-of select="concat('foreign ', $language)"/></xsl:attribute>
    <xsl:apply-templates/>
  </span>
</xsl:template>

<xsl:template match="gap">
  <span class="gap">
    <xsl:if test="not(empty(@xml:id))"><xsl:attribute name="id"><xsl:value-of select="@xml:id"/></xsl:attribute></xsl:if>
    <xsl:attribute name="class"><xsl:value-of select="'gap'"/></xsl:attribute>
    <xsl:if test="not(empty(@extent))"><span class="extent"><xsl:value-of select="string(@extent)"/></span></xsl:if>
    <xsl:apply-templates/>
  </span>
</xsl:template>

<xsl:template match="s">
  <span>
    <xsl:if test="not(empty(@xml:id))"><xsl:attribute name="id"><xsl:value-of select="@xml:id"/></xsl:attribute></xsl:if>
    <xsl:attribute name="class"><xsl:value-of select="'s'"/></xsl:attribute>
    <xsl:apply-templates/>
  </span>
</xsl:template>

<!-- words                            -->
<xsl:template match="*:w">
  <xsl:variable name="wordLanguage" select="@lang"/>
  <xsl:variable name="form" select="encode-for-uri(string(@form))"/>
  <xsl:variable name="dictionary" select="string(@dictionary)"/>
  <xsl:variable name="displayWordOrig">
    <xsl:choose>
      <xsl:when test="not(empty(*:orig))"><xsl:apply-templates select="*:orig/node()"/></xsl:when>
      <xsl:otherwise><xsl:apply-templates/></xsl:otherwise>
    </xsl:choose>
  </xsl:variable>
  <xsl:variable name="displayWordReg">
    <xsl:choose>
      <xsl:when test="not(empty(*:reg))"><xsl:apply-templates select="*:reg/node()"/></xsl:when>
      <xsl:otherwise><xsl:apply-templates/></xsl:otherwise>
    </xsl:choose>
  </xsl:variable>
  <xsl:variable name="displayWordNorm">
    <xsl:choose>
      <xsl:when test="not(empty(*:norm))"><xsl:apply-templates select="*:norm/node()"/></xsl:when>
      <xsl:otherwise><xsl:apply-templates/></xsl:otherwise>
    </xsl:choose>
  </xsl:variable>
  <xsl:variable name="displayWordUrlEncoded" select="encode-for-uri($displayWordOrig)"/>
  <xsl:variable name="dictionaryPart">
    <xsl:choose>
      <xsl:when test="$dictionary = 'true'">
        <a class="dictionary">
          <xsl:attribute name="href"><xsl:value-of select="concat($dictionaryServiceName, '?query=', $form, '&amp;queryDisplay=', $displayWordUrlEncoded, '&amp;language=', $wordLanguage, '&amp;outputFormat=html', '&amp;outputType=morphCompact&amp;outputType=dictFull')"/></xsl:attribute>
          <span class="orig"><xsl:sequence select="$displayWordOrig"/></span>
          <span class="reg"><xsl:sequence select="$displayWordReg"/></span>
          <span class="norm"><xsl:sequence select="$displayWordNorm"/></span>
        </a>
      </xsl:when>
      <xsl:otherwise>
        <span class="dictionary">
          <span class="orig"><xsl:sequence select="$displayWordOrig"/></span>
          <span class="reg"><xsl:sequence select="$displayWordReg"/></span>
          <span class="norm"><xsl:sequence select="$displayWordNorm"/></span>
        </span>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:variable>
  <span class="w">
    <xsl:sequence select="$dictionaryPart"/>
    <span class="nodictionary orig"><xsl:sequence select="$displayWordOrig"/></span>
    <span class="nodictionary reg"><xsl:sequence select="$displayWordReg"/></span>
    <span class="nodictionary norm"><xsl:sequence select="$displayWordNorm"/></span>
  </span>
</xsl:template>

<xsl:template match="*:hi">
  <xsl:choose>
    <xsl:when test="@type = 'elem'">
      <div>
        <xsl:attribute name="class"><xsl:value-of select="concat('highlight ', @type)"/></xsl:attribute>
        <xsl:apply-templates/>
      </div>
    </xsl:when>
    <xsl:otherwise>
      <span>
        <xsl:attribute name="class"><xsl:value-of select="concat('highlight ', @type)"/></xsl:attribute>
        <xsl:apply-templates/>
      </span>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

</xsl:stylesheet>